/*          
    * * * * * * * * * * * * * * * * * * * * * * * * * * * *
            
    Disclaimer:

    This file is being given as an example for automating 
    Registry Related tasks through AutoHotkey Script.     

    You may run this file "ONLY" at your own risk. 

    * * * * * * * * * * * * * * * * * * * * * * * * * * * * 

File Name   : RegPatch_001.ahk

Download    : http://file.autohotkey.net/goyyah/Tips-N-Tricks/RegPatch/RegPatch_001.ahk
SnapShot    : http://file.autohotkey.net/goyyah/Tips-N-Tricks/RegPatch/RegPatch_001.gif
Posted in   : http://www.autohotkey.com/forum/viewtopic.php?p=53455#53455

Main Title  : Registry Patcher Series - Patch 001
Sub Title   : RegPatch - MSIE Suffix

Description :  A GUI to Change the 
               "Microsoft Internet Explorer" suffix that appears on 
               the Title bar of "Internet Explorer Window"

Author      : A.N.Suresh Kumar aka "Goyyah"
Email       : arian.suresh@gmail.com

Created     : 2006-03-15
Modified    : 2006-03-21

Scripted in : AutoHotkey, www.autohotkey.com 

*/


RegRead, MSIE, HKEY_Current_USER
,Software\Microsoft\Internet Explorer\Main
,Window Title
    if errorlevel = 1
       MSIE:="Microsoft Internet Explorer"

Gui, +AlwaysOnTop +ToolWindow
Gui,Font,s12,Courier New
Gui,Add,Edit, x5 y5 w316 h25 Limit27 vNewName,% MSIE
Gui,Font,s10,Verdana
Gui,Add,Button,x+10 y5 h25 w60 gApply,&Apply

Text= 
(Join
This is a Registry Patcher to alter the suffix
 "Microsoft Internet Explorer" (in Internet Explorer
 Title Bar) into any text that you may enter in the 
 above box. `n`n
 Click the "Apply" button to Apply Changes and Exit! `n`n
 No need to restart Windows, but already open
 Browser Windows will not be effected with the change.`n`n
 Open a New "Internet Explorer Window" to see the change.
)

Gui,Font,s8,Verdana
Gui,Add,Text,x5 y+10 w390 Center , %text%
Gui,Show,w400 ,< Registry Patcher > * Change Internet Explorer Suffix *

return

Apply:
  Gui,Submit,NoHide

  RegWrite, REG_SZ, HKEY_Current_USER
  ,Software\Microsoft\Internet Explorer\Main
  ,Window Title, % NewName

  if errorlevel = 1
   {
    Msg=Unable to Write Data!!`n.. The program will exit
    Msgbox,16,<| Registry Patcher |>,%Msg%,5
   }

  ExitApp
Return

GuiClose:
GuiEscape:
    ExitApp
Return